User Tag List

+ Trả lời chủ đề
Hiện kết quả từ 1 tới 7 của 7

Chủ đề: Có Ai Biết Về Bảng Quảng Cáo Không

  1. #1
    NguyenKieuPhong
    Guest

    Có Ai Biết Về Bảng Quảng Cáo Không

    Em đang phải lam bài biển quảng cáo (chữ chạy)dùng AT89S52 ghep nối với LCD hoặc LED ma trận vậy bác nào có tài liệu tham khảo hoặc đã làm thì giới thiệu cho em với

  2. #2
    Forever Young
    Guest

    Mặc định

    làm biển quảng cáo chữ chạy mà dùng VĐK và LCD thì dễ quá rồi, chỉ cần hiểu về hoạt động của VĐK (các chân, ngắt và quan trọng nhất là chương trình điều khiển...), hoạt động của LCD (cách đưa lệnh, đưa dữ liệu hiện thị) là ổn.

  3. #3
    svBK's Member Avatar của blackstar264
    Tham gia ngày
    Apr 2004
    Bài gửi
    49

    Mặc định

    bọn em dang cần lập\ một chương trình kết nối bàn phím với cả 89c51 nhung khó quá. Có anh chi nào k45 có tài liệu về vầndề này ko giới thiệu em với
    Một trái tim giàu lên nhờ những gì nó nhận vào và đẹp lên nhờ những cái nó cho đi.
    Hãy sống để cống hiến !!!!

  4. #4
    binhjuventus
    Guest

    Mặc định

    Quote Nguyên văn bởi blackstar264
    bọn em dang cần lập\ một chương trình kết nối bàn phím với cả 89c51 nhung khó quá. Có anh chi nào k45 có tài liệu về vầndề này ko giới thiệu em với
    Tớ thì kô biết có chương trình nào như thế với 8051 trên net kô (trên diễn đàn điện tử của Tp. HCM hình như có một chương trình thì phải) còn dùng PIC thì đầy!!!

    CLK của bàn phím thường kô biết (nằm trong dải 16 - 22 K), các cậu nên thử sử dụng ngắt xem sao (bọn tớ chưa làm nhưng tới chắc sẽ làm). Cái này hình như bọn nào cũng dùng, kể cả PIC (kô biết đúng kô nhỉ).

    To KieuPhong: Tớ kô làm biển quảng cáo đâu, xin lỗi đã kô trả lời PM vì bận quá!

  5. #5
    svBK's Newbie
    Tham gia ngày
    Nov 2004
    Bài gửi
    3

    Mặc định romodoforever

    Minh cung lam de tai nhu cau va da lam gan xong roi, minh viet bang ASM, DUNG LCD De hien thi, giao tiep voi ban phim so HEX 4x3, tai lieu thi doc trong quyen 8051 cua Nguyen Tang Cuong ay, nhu the la du roi. undefined

  6. #6
    svBK's Newbie
    Tham gia ngày
    Nov 2004
    Bài gửi
    3
    undefinedundefinedROMDOFOREVER
    Created by hvd_hutforever@yahoo.com
    Chuong trinh giao tiep ban phim + vi dieu khien + LCD


    RS BIT P3.0 ;Bit P3.0 dung chon thanh ghi lenh/du lieu
    EN BIT P3.1 ;Bit P3.1 dung lam chan 'Cho phep'
    RW BIT P3.4 ;Bit P3.4 dieu khien viec doc/ghi du lieu

    C1 BIT P1.2 ;Cac bit P1.2, P1.1, P1.0 lan luot noi voi
    C2 BIT P1.1 ;cac cot tu 1 - 3 cua ban phim
    C3 BIT P1.0
    H1 BIT P1.3 ;Cac bit P1.3 - P1.6 lan luot noi voi
    H2 BIT P1.4 ; cac hang tu 1 - 4 cua ban phim
    H3 BIT P1.5
    H4 BIT P1.6

    ORG 0
    Mainpro:
    LCALL Hien_Promt
    LCALL Nhap_Dulieu
    LJMP QuangCao


    Hien_Promt:
    ;1-Hien thi dau nhac nap du lieu
    ;Khoi tao LCD
    MOV A,#38H ;Che do 2 dong ma tran 5x7
    LCALL COMMAND ;Thuc hien lenh
    MOV A,#0EH ;Bat hien thi nhap nhay con tro
    LCALL COMMAND
    MOV A,#01H ;Xoa man hinh hien thi
    CALL COMMAND

    ;gioi thieu cac thanh vien lam de tai
    MOV DPTR,#900H ;Nap con tro du lieu
    MOV R3,#7 ;R3 de chua so chuoi duoc hien thi
    AGAIN: CALL GTTIEP ; GTIEP = gioi thieu tiep
    INC DPTR
    DJNZ R3,AGAIN
    LJMP Xoamanhinh
    GTTIEP:
    BACK1:
    CLR A
    MOVC A,@A+DPTR
    MOV R7,A ;Du cat vao R7 de phuc vu cho HIENTHI1
    JZ TIEPTUC ;Chuyen sang nhap chuoi tiep theo
    LCALL HIENTHI1
    LCALL DELAY
    LCALL DELAY
    INC DPTR
    SJMP BACK1
    TIEPTUC:
    LCALL DELAY
    MOV A,#01 ;Xoa man hinh de hien thi chuoi moi
    LCALL COMMAND
    LCALL DELAY

    RET ; RET OF GTTIEP

    ;Chuong trinh con xuat lenh
    COMMAND: LCALL READY ;Kiem tra co ban neu san sang
    MOV P2,A ;thi chuyen ma lenh ra cong P2
    CLR RS ;RS =0 Cho xuat lenh
    CLR RW ;RW = O De gi lenh toi LCD
    SETB EN ;Chan E nhan duoc mot xung cao
    CLR EN ;xuong thap cho phep LCD chot lenh
    RET ; ret of COMMAND

    xoamanhinh:
    ;giu prompt mot luc, roi xoa man hinh de nhap du lieu
    LCALL DELAY
    MOV A,#01
    LCALL COMMAND
    LJMP Nhap_dulieu

    ;Chuong trinh con hien thi
    HIENTHI1:
    MOV A,#06H ;Chon huong hien thi sang ben phai
    LCALL COMMAND
    LCALL READY
    MOV P2,R7
    SETB RS ;RS = 1 De cho phep xuat du lieu
    CLR RW ;RW = 0 De ghi du lieu ra LCD
    SETB EN ;Chan Enable nha mot xung cao
    CLR EN ;xuong thap de chot du lieu
    RET ;RET of HIENTHI1

    ;Chuong trinh con tao tre
    DELAY:
    MOV R6,#255
    VONG2:MOV R7,#255
    HERE: DJNZ R7,HERE
    DJNZ R6,VONG2
    RET
    ; Kiem tra co ban
    READY: SETB P2.7 ;lay P2.7- chan co ban lam dau vao
    CLR RS ; RS =0 de truy cap thanh ghi lenh
    SETB RW ; RW = 1 Doc thanh ghi lenh
    ;Doc thanh ghi lenh va kiem tra co lenh
    BACK: CLR EN
    SETB EN
    JB P2.7,BACK ;cho cho den khi LCD het ban
    RET ;Of ready



    ;CHUONG TRINH CON GIAO TIEP VOI BAN PHIM
    ;P1.1 P1.2 P1.3 duoc noi voi cac cot 3 2 1
    ;P1.4 P1.5 P1.6 P1.7 duoc noi voi cac hang 1 2 3 4
    Nhap_Dulieu:
    ;Doan nay phuc vu cho viec luu Du lieu vao vung RAM da nang
    MOV R1,#30H ;R1 dung lam con tro ram,phuc vu cho
    ; viec luu giu du lieu vao RAM
    MOV R2,#4FH ; do lon khong gian RAM dan nang
    Xoaram: MOV @R1,#20H ;20h ma ASCII cua ky tu trang ' '
    INC R1
    DJNZ R2,Xoaram

    MOV R1,#30H
    MOV R5,#0 ;dem so ky tu hien tai dang hien thi tren LCD
    ;doan nay chi nhan biet xem la co phim nhan chua
    ; nen ta tiep dat tat ca cac hang
    batdau:
    MOV P1,#00000111b ;De co the nhan biet duoc phim da nhan
    ; chua ta dat cac bit tuong ung voi
    ;cac cot lam dau vao va cac bit tuong
    ;ung voi hang duoc noi dat
    MOV R0,#0 ;vi moi phim co the hien thi 4 ky tu
    ;ta dung R0 de xac dinh so ky tu tren
    ; mot phim da duoc nhan la bao nhieu
    KT1:
    MOV A,P1
    CJNE A,#00000111b,KT1 ;Kiem tra nha phim chua,neu chua
    ;kiem tra lai cho den khi nha phim

    KT2: LCALL DELAY
    MOV A,P1 ; De doc cac cot
    CJNE A,#00000111b,CHO1 ; Neu phim nhan cho xong
    SJMP KT2 ; Neu khong thi kiem tra lai xem no co duoc nhan ko

    CHO1:
    MOV R0,#0
    LCALL DELAY ; Cho cho nhan xong
    CJNE A,#00000111b,CHO2 ;Neu co phim nhan thi nhay den
    ;CHO2 cho hien thi phim do va
    ;tiep tuc kiem tra xem phim do
    ; co duoc nhan tiep ngay khong
    SJMP KT2

    CHO2:
    INC R0 ;Da co mot phim duoc nhan 1 lan
    LCALL HIEN ; hien thi ky tu do
    LCALL DELAY
    LCALL DELAY
    MOV P1,#00000111B ;kiem tra co phim nhan tiep khong
    LCALL DELAY
    MOV A,P1
    CJNE A,#00000111b,CHO3
    MOV A,R4 ;luu ky tu duoc hien thi cuoi
    ;cung cua phim nhan vao RAM
    MOV @R1,A
    INC R1
    INC R5
    ;Doan nay dung de dich man hinh hien thi sang phai khi so
    ;ky tu da hien thi lon hon 16
    CLR C
    MOV A,R5
    SUBB A,#16
    JC TIEP1
    MOV A,#18H
    LCALL COMMAND
    ;het doan dich hien thi sang phai
    TIEP1:MOV R0,#0
    SJMP KT2

    CHO3:MOV A,#10H
    LCALL COMMAND
    INC R0
    LCALL HIEN
    LCALL DELAY
    LCALL DELAY
    MOV P1,#00000111B
    LCALL DELAY
    MOV A,P1
    CJNE A,#00000111b,CHO4
    MOV A,R4
    MOV @R1,A
    INC R1
    INC R5
    CLR C
    MOV A,R5
    SUBB A,#16
    JC TIEP2
    MOV A,#18H
    LCALL COMMAND
    TIEP2:
    MOV R0,#0
    SJMP KT2
    CHO4:MOV A,#10H
    LCALL COMMAND
    INC R0
    LCALL HIEN
    LCALL DELAY
    LCALL DELAY
    MOV P1,#00000111B
    LCALL DELAY
    MOV A,P1
    CJNE A,#00000111b,CHO5
    MOV A,R4
    MOV @R1,A
    INC R1
    INC R5
    CLR C
    MOV A,R5
    SUBB A,#16
    JC TIEP3
    MOV A,#18H
    LCALL COMMAND

    TIEP3: MOV R0,#0
    JMP KT2
    CHO5:MOV A,#10H
    LCALL COMMAND
    INC R0
    LCALL HIEN
    LCALL DELAY
    LCALL DELAY
    MOV P1,#00000111B
    LCALL DELAY
    MOV A,P1
    CJNE A,#00000111b,VONGVE
    MOV A,R4
    MOV @R1,A
    INC R1
    INC R5
    CLR C
    MOV A,R5
    SUBB A,#16
    JC TIEP4
    MOV A,#18H
    LCALL COMMAND
    TIEP4: MOV R0,#0
    VONGVE: LJMP KT2

    :a37

  7. #7
    svBK's Newbie
    Tham gia ngày
    Nov 2004
    Bài gửi
    3

    Mặc định

    doan tiep

    HIEN:
    Timhang:
    MOV P1,#11111111B ;DAU TIEN KO TIEP DAT HANG NAO
    ;VA DAT CAC COT LAM DAU VAO
    CLR H1 ;Tiep dat hang 1
    MOV A,P1 ;Doc tat ca cac cot
    CJNE A,#11110111b,HG1
    ;Hang 1 tim cot (ro rang la cac hang tuong ung voi 5 bit
    ;dau la co dinh=11110 do chi tiep dat hang1, tai day
    ;ta chi can quan tam den phim co phai o hang 1 khong thoi
    ; boi vay chi can co 1 trong 3 cot duoc nhan se lam cho
    ;1 cot tiep dat dan den 1 trong 3 bit dau =0 nhu vay
    ; khi do gia tri A se khac #11110111 chung to phim nhan
    ; o hang 1 va ta tiep tuc xac dinh phim do o cot nao
    MOV P1,#11111111B
    CLR H2 ;Tiep dat hang 2
    MOV A,P1 ;Doc tat ca cac cot
    CJNE A,#11101111b,HG2 ;Hang 1 tim cot

    MOV P1,#11111111B
    CLR H3 ;Tiep dat hang 3
    MOV A,P1 ;Doc tat ca cac cot
    CJNE A,#11011111b,HG3 ;Hang 3 tim cot

    MOV P1,#11111111B
    CLR H4 ;Tiep dat hang 4
    MOV A,P1 ;Doc tat ca cac cot
    CJNE A,#10111111b,HG4 ;Hang 4 tim cot
    LJMP KT2

    HG1: CJNE R0,#1,DT12
    MOV DPTR,#DATA11
    LJMP TIM ;Tim xem phim nhan o cot nao

    DT12: CJNE R0,#2,DT13
    MOV DPTR,#DATA12
    LJMP TIM

    DT13: CJNE R0,#3,DT14
    MOV DPTR,#DATA13
    LJMP TIM
    ;Neu khong phai la cac truong hop tren thi R0 = 4
    ; ta tim luon den data14
    DT14: MOV DPTR,#DATA14
    LJMP TIM

    HG2: CJNE R0,#1,DT22
    MOV DPTR,#DATA21
    LJMP TIM

    DT22: CJNE R0,#2,DT23
    MOV DPTR,#DATA22
    SJMP TIM

    DT23: CJNE R0,#3,DT24
    MOV DPTR,#DATA23
    SJMP TIM
    DT24: MOV DPTR,#DATA24
    SJMP TIM

    HG3: CJNE R0,#1,DT32
    MOV DPTR,#DATA31
    SJMP TIM

    DT32: CJNE R0,#2,DT33
    MOV DPTR,#DATA32
    SJMP TIM

    DT33: CJNE R0,#3,DT34
    MOV DPTR,#DATA33
    SJMP TIM
    DT34: MOV DPTR,#DATA34
    SJMP TIM

    HG4: CJNE R0,#1,DT42
    MOV DPTR,#DATA41
    SJMP TIM

    DT42: CJNE R0,#2,DT43
    MOV DPTR,#DATA42
    SJMP TIM

    DT43: CJNE R0,#3,DT44
    MOV DPTR,#DATA43
    SJMP TIM

    DT44: MOV DPTR,#DATA44
    SJMP TIM
    TIM:
    RRC A ;Kiem tra cot nao o muc thap nho co CY
    JNC LAYMA ;Neu bang 0 thi lay ma ASCII
    INC DPTR ;Trai lai tim cot ke
    SJMP TIM

    LAYMA:CLR A
    MOVC A,@A + DPTR
    JZ Ketthucnhap
    MOV R4,A

    CJNE A,#23h,SS2 ; a= '#' ,ta quy uoc la phim xoa
    JMP backspace
    SS2 : CJNE A,#24h,SS3 ;quy uoc '$' la ma xuong dong
    LCALL Xuongdong
    SS3 :
    LCALL HienThiPhimNhan ;hien thi phim da nhan
    VE: RET ;OF HIEN

    BACKSPACE:
    ;doan nay de xoa ca ky tu do da duoc luu trong RAM
    DEC R1
    DEC R5
    DEC R1
    DEC R5
    MOV A,@R1
    MOV R4,A
    ;Doan nay de xoa ky tu tren LCD
    MOV A,#10H ;dich con tro sang phai mot cot
    LCALL COMMAND
    MOV A,#20H ;chen ky tu trang vao vi tri do
    LCALL HIENTHIPHIMNHAN
    MOV A,#10H ;lui ve 1 cot
    LCALL COMMAND
    JMP VE
    ketthucnhap: ;do khoang cach tu doan lay ma
    LJMP quangcao ;den doan quangcao nam ngoai
    ;dai cua lenh JZ nen ta dung
    ;doan nay de noi tiep
    xuongdong: MOV A,#0C0H
    LCALL COMMAND
    JMP VE
    Hienthiphimnhan:
    LCALL READY
    MOV P2,A
    SETB RS ;RS = 1 De cho phep xuat du lieu
    CLR RW ;RW = 0 De ghi du lieu ra LCD
    SETB EN ;Chan Enable nha mot xung cao
    CLR EN ;xuong thap de chot du lieu
    LCALL DELAY
    RET


    QUANGCAO:




    MOV A,R5
    MOV R3,A
    ;Xoa tung ky tu
    CHAY1: Mov a,#10h
    Lcall command
    MOV A,#20h
    LCALL HIENTHIPHIMNHAN
    Mov a,#10h
    Lcall command
    LCALL DELAY
    DJNZ R5,CHAY1
    ;hien thi lai tung ky tu

    MOV R1,#30H
    HTL:
    MOV A,@R1
    MOV R7,A
    LCALL Hienthi1
    LCALL DELAY
    LCALL DELAY
    LCALL DELAY
    TIEP: INC R1
    DJNZ R3,HTL
    MOV R4,#5
    FOREVER:
    MOV R4,#5
    NHAPNHAY: MOV A,#0AH ;Xoa man hinh hien thi
    LCALL COMMAND
    LCALL DELAY ;de man hinh tat mot luc
    LCALL DELAY
    LCALL DELAY
    LCALL DELAY
    LCALL DELAY
    MOV A,#0eH ;Bat man hinh hien thi
    LCALL COMMAND
    LCALL DELAY ; de mot luc
    LCALL DELAY
    LCALL DELAY
    LCALL DELAY
    DJNZ R4,NHAPNHAY
    LCALL DELAY
    LCALL DELAY
    MOV R4,#40 ; vi LCD co 40 cot, nen cuoi cung
    ;hien thi se dich ve dung vi tri cu
    DichTrai: Mov A,#18H
    LCALL COMMAND
    LCALL DELAY
    LCALL DELAY
    LCALL DELAY
    DJNZ R4,DichTrai

    LCALL DELAY
    LCALL DELAY
    MOV R4,#40
    DichPhai: Mov A,#1CH
    LCALL COMMAND
    LCALL DELAY
    LCALL DELAY
    DJNZ R4,DichPhai

    LJMP FOREVER



    ORG 900H
    DANHSACH: DB "Nhom thuc hien: ",0
    SV1: DB "Hoang Van Dong",0
    SV2: DB "Tran Xuan Ngoc",0
    SV3: DB "Ng_Trung Kien",0
    SV4: DB "Vu Van Dinh",0
    SV5: DB "Tran Do",0
    DULIEU: DB "Nhap du lieu...",0

    ORG 1000H
    DATA11: DB '1','2','3'
    DATA12: DB '1','A','D'
    DATA13: DB '1','B','E'
    DATA14: DB '1','C','F'



    DATA21: DB '4','5','6'
    DATA22: DB 'G','J','M'
    DATA23: DB 'H','K','N'
    DATA24: DB 'I','L','O'

    DATA31: DB '7','8','9'
    DATA32: DB 'P','T','W'
    DATA33: DB 'R','U','X'
    DATA34: DB 'S','V','Y'

    DATA41: DB '#',' ',0
    DATA42: DB ' ','0',0
    DATA43: DB '$','_',0
    DATA44: DB '#','@',0

    END

+ Trả lời chủ đề

Thông tin chủ đề

Users Browsing this Thread

Hiện có 1 người đọc bài này. (0 thành viên và 1 khách)

Từ khóa (Tag) của chủ đề này

Quyền viết bài

  • Bạn không thể gửi chủ đề mới
  • Bạn không thể gửi trả lời
  • Bạn không thể gửi file đính kèm
  • Bạn không thể sửa bài viết của mình


About svBK.VN

    Bách Khoa Forum - Diễn đàn thảo luận chung của sinh viên ĐH Bách Khoa Hà Nội. Nơi giao lưu giữa sinh viên - cựu sinh viên - giảng viên của trường.

Follow us on

Twitter Facebook youtube